stn := @use("../../../libraries/stn/src/lib.hb");
.{string, memory, buffer, random, log} := stn;
.{Vec2} := stn.math

horizon_api := @use("../../../libraries/horizon_api/src/lib.hb")

render := @use("../../../libraries/render/src/lib.hb")

Window := struct {
	// TODO: Replace this with widgets
	implicit_framebuffer: render.Surface,
	width: int,
	height: int,
	x: int,
	y: int,
}

psf := @embed("../../../consolefonts/tamsyn/10x20r.psf")

main := fn(): int {
	win_buff := buffer.create("XHorizon\0")

	screen := render.init(true)

	// Clear the screen to black.
	render.clear(screen, render.black)

	window := render.new_surface(screen.width / 3, screen.height / 3)

	x := 0

	mem_buf := memory.request_page(1)
	color := random.any(render.Color)
	side := window.width / 8

	vel_inner := Vec2(int).(1, 1)
	pos_inner := Vec2(uint).((window.width - side) / 2, (window.height - side) / 2)
	str := "Window Title Bar\0"
	font := render.text.font_from_psf2(@bitcast(&psf))

	loop {
		// Clear the screen
		render.clear(screen, render.black)

		// TODO: Read the window buffer here
		{
			ret := buffer.recv([u8; 4096], win_buff, mem_buf)
			if ret == 0 {
				log.info("No messages\0")
			} else {
				log.info("Handle Messages\0")
			}
		}

		if pos_inner.x == 0 | pos_inner.x == window.width - side {
			vel_inner.x = -vel_inner.x
			color = random.any(render.Color)
		}
		if pos_inner.y == 20 | pos_inner.y == window.height - side {
			vel_inner.y = -vel_inner.y
			color = random.any(render.Color)
		}

		// TODO: Get windows out of a collection and iter through
		window_count := 0
		loop {
			render.clear(window, render.black)
			render.put_rect(screen, .(0, 0), .(screen.width - 1, screen.height - 1), render.white)

			// Draw the decorators
			{
				render.put_rect(window, .(0, 0), .(window.width - 1, window.height - 1), render.white)
				render.put_rect(window, .(0, 0), .(window.width - 1, 20), render.white)
				render.put_text(window, font, .(window.width / 2, 1), render.white, str)
			}
			render.put_filled_rect(window, pos_inner, .(side, side), color)

			// Apply the image to the screen
			pos := Vec2(uint).(x, 100)

			render.put_surface(screen, window, pos, false)
			if window_count >= 1 {
				x = 0
				break
			}
			window_count += 1
			x += screen.width / 2
		}
		pos_inner += @bitcast(vel_inner)

		// Sync the screen
		render.sync(screen)
	}

	return 0
}