ableos_time/sysdata/libraries/stn/src/memory.hb

PAGE_SIZE := 4096
MAX_ALLOC := 0xFF
MAX_FREE := 0xFF

calc_pages := fn($Expr: type, num: uint): uint {
	return 1 + @sizeof(Expr) * num / PAGE_SIZE
}

alloc := fn($Expr: type, num: uint): ^Expr {
	pages := @inline(calc_pages, Expr, num)
	if pages <= MAX_ALLOC {
		return @bitcast(request_page(@intcast(pages)))
	}
	ptr := request_page(0xFF)
	remaining := pages - MAX_ALLOC
	loop if remaining < MAX_ALLOC break else {
		_ := request_page(@intcast(MAX_ALLOC))
		remaining -= MAX_ALLOC
	}
	_ := request_page(@intcast(remaining))
	return @bitcast(ptr)
}

// ! stub
free := fn($Expr: type, ptr: ^Expr, num: uint, nullify: bool): void {
	return
}

RqPageMsg := packed struct {a: u8, count: u8}
request_page := fn(count: u8): ^u8 {
	return @eca(3, 2, &RqPageMsg.(0, count), @sizeof(RqPageMsg))
}

RlPageMsg := packed struct {a: u8, count: u8, ptr: ^u8}
release_page := fn(ptr: ^u8, count: u8): void {
	return @eca(3, 2, &RlPageMsg.(1, count, ptr), @sizeof(RlPageMsg))
}

OutbMsg := packed struct {a: u8, b: u8, addr: u16, value: u8}
outb := fn(addr: u16, value: u8): void {
	return @eca(3, 3, &OutbMsg.(1, 0, addr, value), @sizeof(OutbMsg))
}

InbMsg := packed struct {a: u8, b: u8, addr: u16}
inb := fn(addr: u16): u8 {
	return @eca(3, 3, &InbMsg.(0, 0, addr), @sizeof(InbMsg))
}

OutlMsg := packed struct {a: u8, b: u8, addr: u16, value: u32}
outl := fn(addr: u16, value: u32): void {
	return @eca(3, 3, &OutlMsg.(1, 2, addr, value), @sizeof(OutlMsg))
}

InlMsg := packed struct {a: u8, b: u8, addr: u16}
inl := fn(addr: u16): u32 {
	return @eca(3, 3, &InlMsg.(0, 2, addr), @sizeof(InlMsg))
}

CopyMsg := packed struct {a: u8, count: u32, src: ^u8, dest: ^u8}
copy := fn($Expr: type, src: ^Expr, dest: ^Expr, count: uint): void {
	return @eca(3, 2, &CopyMsg.(4, @intcast(count * @sizeof(Expr)), @bitcast(src), @bitcast(dest)), @sizeof(CopyMsg))
}

SetMsg := packed struct {a: u8, count: u32, size: u32, src: ^u8, dest: ^u8}
set := fn($Expr: type, src: ^Expr, dest: ^Expr, count: uint): void {
	return @eca(3, 2, &SetMsg.(5, @intcast(count), @intcast(@sizeof(Expr)), @bitcast(src), @bitcast(dest)), @sizeof(SetMsg))
}