.{memory, log, string} := @use("../../../libraries/stn/src/lib.hb")
format_page := memory.dangling(u8)

DeviceID := struct {value: u16}

$Mouse3Button := DeviceID.(0x0)
$MouseScrollwheel := DeviceID.(0x3)
$Mouse5Button := DeviceID.(0x4)
$Spacesaver := DeviceID.(0x84AB)
$Keyboard122Key := DeviceID.(0x86AB)
$KeyboardJapaneseG := DeviceID.(0x90AB)
$KeyboardJapanesep := DeviceID.(0x91AB)
$KeyboardJapaneseA := DeviceID.(0x92AB)
$KeyboardNCDSun := DeviceID.(0xA1AC)
$NoDevice := DeviceID.(0xFFFF)

State := struct {value: u8}
$Recive := State.(0)
$Reboot := State.(1)
$GetID := State.(2)
$TurnOnStreaming := State.(3)

CommandQueue := struct {queue: [u8; 8]}

Port := struct {exists: bool, device: DeviceID, commands_queued: u8, command_queue: [u8; 8], command_index: u8, awaiting_acks: u8, state: State, expecting: bool}

$check_bit := fn(value: u8, bit: u8, state: u8): bool {
	return (value >> bit & 1) == state
}

ports := [Port].(.(true, NoDevice, 1, .(0xFF, 0, 0, 0, 0, 0, 0, 0), 0, 0, Reboot, false), .(true, NoDevice, 1, .(0xFF, 0, 0, 0, 0, 0, 0, 0), 0, 0, Reboot, false))

$send_byte := fn(port: uint, value: u8): void {
	//Sending over 8 bytes will cause and overflow, don't do pwease?
	ports[port].command_queue[(ports[port].command_index + 1) % 8] = value
	ports[port].awaiting_acks += 1
}

initialize_controller := fn(): void {
	memory.outb(0x64, 0xAD)
	memory.outb(0x64, 0xA7)
	//Disables ports to make sure that they won't interfere with the setup process.

	loop if (memory.inb(0x64) & 1) == 0 break else memory.inb(0x60)
	//Flushes any output because apperantly that might interfere with stuff.

	memory.outb(0x64, 0xA8)
	//Enables port 2.
	memory.outb(0x64, 0x20)
	//Gimme configuration byte.
	loop if (memory.inb(0x64) & 1) == 1 break
	ports[1].exists = check_bit(memory.inb(0x60), 5, 0)
	if ports[1].exists {
		memory.outb(0x64, 0xA7)
	}

	loop if (memory.inb(0x64) & 1) == 0 break else memory.inb(0x60)
	//Flushes any output because apperantly that might interfere with stuff.

	memory.outb(0x64, 0xAB)
	loop if (memory.inb(0x64) & 1) == 1 break
	ports[0].exists = memory.inb(0x60) == 0x0
	//Test port 1.

	if ports[1].exists {
		memory.outb(0x64, 0xA9)
		loop if (memory.inb(0x64) & 1) == 1 break
		ports[1].exists = memory.inb(0x60) == 0x0
	}
	//Test port 2.

	if (ports[0].exists | ports[1].exists) == false {
		log.error("No ports detected! No input will be processed! Cannot handle this!\0")
	}

	if ports[0].exists {
		log.info("Port 1 exists.\0")
		memory.outb(0x64, 0xAE)
		//Enables port 1.
		ports[0].commands_queued = 1
	}
	if ports[1].exists {
		log.info("Port 2 exists.\0")
		memory.outb(0x64, 0xA8)
		//Enables port 2.
		ports[1].commands_queued = 1
	}
}

handle_input := fn(port: uint, input: u8): void {
	if input == 0xAA {
		log.info("Device rebooted!\0")
		log.info(string.display_int(@intcast(port + 1), format_page, 16))
		ports[port].state = GetID
		send_byte(port, 0xF2)
		//Get ID
	} else if ports[port].state.value == Recive.value {
	}
}

main := fn(): void {
	format_page = memory.alloc(u8, 1024)

	@inline(initialize_controller)

	loop {
		port_info := memory.inb(0x64)
		//Enables port 1.
		if (port_info & 0x40) > 0 {
			log.error("Timeout error! Cannot handle these!\0")
		}
		if (port_info & 0x80) > 0 {
			log.error("Parity error! Cannot handle these!\0")
		}

		if (port_info & 1) == 0 {
			if ports[0].exists & ports[0].commands_queued > 0 {
				memory.outb(0x60, ports[0].command_queue[ports[0].command_index])
				ports[0].commands_queued -= 1
				ports[0].command_index = (ports[0].command_index + 1) % 8
			}
			if ports[1].exists & ports[1].commands_queued > 0 {
				memory.outb(0x64, 0xD4)
				memory.outb(0x60, ports[1].command_queue[ports[1].command_index])
				ports[1].commands_queued -= 1
				ports[1].command_index = (ports[1].command_index + 1) % 8
			}
		}

		port := 0
		if ports[1].exists {
			port = port_info >> 5 & 1
		}

		if ports[port].exists {
			input := memory.inb(0x60)
			if ports[port].awaiting_acks > 0 & input == 0xFA {
				ports[port].awaiting_acks -= 1
			} else {
				@inline(handle_input, port, input)
			}
		}
	}
}