ableos/sysdata/libraries/sunset_proto/src/server.hb

.{math, log, string, random, buffer, memory} := @use("../../stn/src/lib.hb");
.{Color, Surface, new_surface, put_surface, sync, put_rect, put_filled_rect, text, put_text} := @use("../../render/src/lib.hb");
.{Channel, Window, WindowProps, WindowData, MessageHeader, BUFFER_SERVER, BUFFER_CLIENT, message, permissions, recv_header, recv_message, send_message, send_header, await_message} := @use("./lib.hb")

WindowServer := struct {
	window_count: uint,
	channel: Channel,
	// ! replace this with a collection when we get an allocator
	windows: [?WindowData; 10],
	font: text.Font,
}

// ! in the future this should be safely handled
server := @as(WindowServer, idk)

psf := @embed("../../../assets/consolefonts/tamsyn/10x20r.psf")

start := fn(): void {
	font := text.font_from_psf2(@bitcast(&psf), false)
	if font == null {
		log.error("server: failed to load asset\0")
		return
	}
	server = .(0, .{client: buffer.create(BUFFER_CLIENT), server: buffer.create(BUFFER_SERVER)}, .(null, null, null, null, null, null, null, null, null, null), @as(text.Font, font))
	log.info("server: started server\0")
}

incoming := fn(): bool {
	msg := recv_header(server.channel.server)
	if msg == null {
		return true
	}
	if msg.kind == message.syn {
		log.info("server: recv syn\0")
		channel := Channel.(buffer.create_nameless(), buffer.create_nameless())
		send_message(Channel, message.ack, channel, server.channel.client)
		props := await_message(WindowProps, channel.server)
		if props.header.kind != message.props {
			return true
		}
		log.info("server: recv props\0")
		// ! do inspection of requested props here
		data := WindowData.(props.body, channel, permissions.default)
		send_message(WindowData, message.ack, data, channel.client)
		server.windows[server.window_count] = data
		server.window_count += 1
	}
	return true
}

render_clients := fn(screen: Surface): void {
	// support one window for test case
	window := server.windows[0]
	if window == null {
		return
	}
	header := recv_header(window.channel.server)
	if header == null {
		return
	}
	if header.kind != message.frame_ready {
		return
	}
	send_header(message.ack, window.channel.client)
	ptr := await_message(^Color, window.channel.server)
	if ptr.header.kind != message.ack {
		return
	}
	put_surface(screen, .(ptr.body, window.props.dimensions.x, window.props.dimensions.y, window.props.dimensions.x * window.props.dimensions.y), window.props.position, false)
	put_rect(screen, window.props.position - .(1, 1), window.props.dimensions + .(1, 1), .(255, 255, 255, 255))
	put_filled_rect(screen, window.props.position - .(1, 21), .(window.props.dimensions.x + 2, 20), .(255, 255, 255, 255))
	put_text(screen, server.font, window.props.position - .(-2, 20), .(0, 0, 0, 255), window.props.title)
	sync(screen)
	send_header(message.ack, window.channel.client)
}